;noesy_nhsqc_noD_Lsw_ydw
;avance-version
; modified from noesy_hsqc_ydw to suppress diagonal peaks
;2D H-1/X correlation via double inept transfer
;   using sensitivity improvement
;phase sensitive using Echo/Antiecho-TPPI gradient selection
;with decoupling during acquisition
;
; For 15N,13C-labeled samples, activate Cflg
; d8 NOE mixing time
; d9 slightly shorter than d8, which can be adjusted by recording a f2f3 plane
; The best value will give rise to a difference spectrum without diagonal 
; when the post-processing factor is set to 1.

; NS = 4*n
; p1 @PL1, 1H 90 pulse; p2=2*p1
; p11@PL11, 1H soft 90 pulse used for water flip-back, p11~2000us
; p3 @PL3, 15N 90 pulse; p4=2*p3
; PL13, 15N decoupling power (pcpd3 = 200 us @800 MHz; 250 us @500 MHz)
; p5 @PL2, 13C 90 pulse; p6=2*p6
; when p5*4+6u>p4, change d26 as "d26=2*d0+p4"

; gpz1:gpz2=80:8.05


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

;
#define Nflg
;#define Cflg

"p2=p1*2"
"p4=p3*2"
"p6=p5*2"
"d0=3u"
"d10=3u"
"d4=2.3m-p17-d16"
"d6=2.3m-p17-d16-p1*4/3.1416"
"d7=2.3m-p17-d16-4u"
"d11=30m"
"d13=4u"
"CEN_HN2=(p4-p2)/2"
"CEN_HN3=(p3-p1)/2"
"CEN_HC2=(p12-p2)/2"

"d5=d4-CEN_HN3"

"d21=p16+d16+p2+d10*2+4*p5+6u"
"d22=p16+d16+p2+d10*2"
"DELTA1=d13+p16+d16+4u-2*p1/3.1416"
"DELTA=d1-d11-57m"
"d25=2*d0+p4"
"d26=2*d0+p6+2*p5+6u"

"l3=(td1/2)"
"l13=(td2/2)"
"l0=1"

aqseq 321

1 ze
  d11 pl13:f3
2 d11 do:f3
  6m 
3 3m
4 18m 
5 10m
6 10m 
7 10m pl3:f3 pl2:f2
  DELTA
  50u UNBLKGRAD
  (p3 ph1):f3
  p17:gp3
  d16 pl1:f1

  (p1 ph8):f1
  d0
#ifdef Cflg
  (p5 ph2 3u p6 ph1 3u p5 ph2):f2 (p4 ph1):f3
#endif
#ifdef Nflg
  (p4 ph1):f3
#endif
  d0
  (p2 ph10):f1
#ifdef Nflg
  d25
#endif
#ifdef Cflg
  d26
#endif
  (p1 ph1:r):f1
  p18:gp5
  d16

  if "l0 %2 == 1" goto 98
;both diagonal and cross, NOE period
  d8

;refocus
  (p1 ph1)
  p17:gp4
  d16
  d7
  4u 
  (CEN_HN2 p2 ph1) (p4 ph6):f3
  4u
  p17:gp4
  d16
  d7
  (p1 ph2):f1
  3u pl11:f1
  (p11 ph1):f1
  3u
  3u pl1:f1

   goto 99

; diagonal

;refocus
98 3u
  (p1 ph1)
  p17:gp4
  d16
  d7
  4u
  (CEN_HN2 p2 ph1) (p4 ph6):f3
  4u
  p17:gp4
  d16
  d7
  (p1 ph2):f1
  3u pl11:f1
  (p11 ph1):f1
  3u
  3u pl1:f1

  d9

99 3u
   p19:gp6
   d16

  (p3 ph3):f3
  d10
  p2 ph7
#ifdef Cflg
  (p5 ph2):f2
  3u
  (p6 ph1):f2
  3u
  (p5 ph2):f2
#endif
  p16:gp1*EA
  d16
  d10
  (p4 ph1):f3
#ifdef Cflg
  d21
#endif
#ifdef Nflg
  d22 
#endif
  (CEN_HN3 p1 ph1) (p3 ph4):f3
  p17:gp3
  d16
  d4
  (CEN_HN2 p2 ph1) (p4 ph1):f3
  p17:gp3
  d16
  d4
  (CEN_HN3 p1 ph2) (p3 ph2):f3
  p17:gp3
  d16
  d5
  (CEN_HN2 p2 ph1) (p4 ph1):f3
  p17:gp3
  d16
  d4
  (p1 ph11)
  DELTA1
  (p2 ph1)
  d13
  p16:gp2
  d16 pl13:f3 
  4u BLKGRAD
  go=2 ph31 cpd3:f3
  d11 do:f3 wr #0 if #0 zd
  3m ip4 igrad EA
  3m ip4
  lo to 3 times 2
  3m iu0
  lo to 4 times 2
  6m id10
  3m 
  3m 
  3m 
  3m
  lo to 5 times l13
  5m  ip8
  5m rd10
  lo to 6 times 2
  5m id0
  5m ip31*2
  lo to 7 times l3
exit

ph1=0
ph2=1
ph3=0 2
ph4=0
ph5=1
ph6=0
ph7=0
ph8=0 0 2 2
ph9=3
ph10=0
ph11=2
ph31=0 2 2 0