;noesy_nc_4d_ngd_ydw
;avance-version
;4D 13C,15N-edited NOESY (HMQC-NOESY-HSQC), used for proteins larger than 25 kDa
;F1 1H (constant-time acq mode, maximum aq time 4.8ms), F2 13C (both aliphatic and aromatic), 
;F3 15N, and F4 1HN
;without gradient enhancement
;water suppresion with water gate;

;Written by Daiwen Yang in Jan. 2006


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"p4=p3*2"
"p6=p5*2"
"d0=(in0-p5*4/3.1416-p4)/2"
"d10=(in10-p3*4/3.1416-p5-3u-p6-3u-p5)/2"
"d20=3u"
"d4=2.25m-p26-d16-3u-p11-3u-p1*2/3.1416"
"d5=2.25m-p26-d16-3u-p11-3u"
"d24=2.25m-p19-d16"
"d11=30m"
"d13=3u"
"CEN_HC2=(p6-p2)/2"
"CEN_HN2=(p4-p2)/2"

"d6=1.5m-p16-d16-d20"
"d29=1.5m-p16-d16-3u"
"d8=d9-p18-d16-p3"

"in29=in20"

"DELTA=d1-d11-84m"

"l3=(td1/2)"
"l13=(td2/2)"
"l23=30"         ;set a proper number so that l23*4*in20<=4.8 ms

1 ze
  d11  
2 d11 do:f3
  6m  
3 18m 
4 10m
5 10m
6 10m
7 10m 
8 10m do:f3 
  DELTA pl3:f3 pl2:f2 pl1:f1

  50u UNBLKGRAD
  10m
  (p5 ph1):f2
  p17:gp1
  d16

  (p1 ph8):f1
  p16:gp2	;p16 200u
  d16		;d16 100u 
  d20
  d6		; 1.5m-p16-d16
  (center (p2 ph1):f1 (p14:sp2 ph1):f2)
  3u
  p16:gp3
  d16 
  d29		;   1.5m-p16-d16
  (p5 ph6):f2
  d0		;t1 period for 13C 
  (center (p2 ph1):f1 (p4 ph1):f3)
  d0
  (p5 ph1):f2
  p16:gp3
  d16 
  d20
  d6		; 1.5m-p16-d16
  (center (p2 ph1):f1 (p14:sp2 ph1):f2)
  3u
  p16:gp2
  d16 
  d29		;   1.5m-p16-d16
  (p1 ph1:r):f1

  d8		;d8=d9-p18-d16-p3
 (p3 ph1):f3
  p18:gp4
  d16 

  (p1 ph1):f1
  p19:gp8
  d16
  d24 
  (center (p2 ph1):f1 (p4 ph1):f3)
  p19:gp8
  d16
  d24
  (p1 ph2):f1
  3u pl11:f1
  3u
  (p11:sp1 ph11):f1
  3u
  p25:gp5			;1.5m
  d16 pl1:f1 

  (p3 ph3):f3
  d10
  (p1 ph1 3u p2 ph2 3u p1 ph1):f1 (p5 ph1 3u p6 ph2 3u p5 ph1):f2
  d10
  (p3 ph1):f3

  p29:gp7
  d16
 
  3u pl11:f1
  (p11:sp1 ph11):f1
  3u
  3u pl1:f1
  (p1 ph1):f1
  p26:gp6		;500u
  d4
  d16
  3u pl11:f1
  (p11:sp1 ph11):f1
  3u
  3u pl1:f1
  (center (p2 ph1):f1 (p4 ph1):f3)
  3u pl11:f1
  (p11:sp1 ph11):f1
  3u
  3u pl1:f1
  p26:gp6
  d5 BLKGRAD
  d16 pl12:f3 
  go=2 ph31 cpd3:f3
  d11 do:f3 wr #0 if #0 zd
  6m ip3
  lo to 3 times 2
  6m id10
  12m ip31*2
  lo to 4 times l13
  10m rd10 ip6
  lo to 5 times 2
  5m id0
  5m ip31*2
  lo to 6 times l3
  5m rd0
  5m ip8
  lo to 7 times 2
  3m id20
  3m dd29
  4m ip31*2
  lo to 8 times l23

exit

ph1=0
ph2=1
ph3=0 0 2 2
ph6=0 2
ph8=0
ph11=2
ph31=0 2 2 0


;Channel 1 1H
;o1p:	4.7ppm (water)
;p1:	90 degree hard pulse @PL1
;p2:	180 degree hard pulse P2=2*P1
;p11:	90 degree Sinc shaped-pulse @PL11/SP1, ~1.4ms at 800 MHz; on-resonance

;Channel 2 13C
;o2p:	63ppm 
;p5:	90 degree hard pulse @PL2
;p6:	180 degree hard pulse, P6=2*P5

;Channel 3 15N
;o3p: 	119ppm
;p3:	90 degree hard pulse @PL3
;p4:	180 degree hard pulse, P4=2*P3
;PCPD3:	90 degree pulse @PL12, 200us at 800 MHz
;CPDPRG3:	GARP

;in0: 	1/SW(C)/2;
;in10:	1/SW(N)/2;
;in20:	1/SW(H)/4;
;in29:	=in20
;l3:	td1/2
;l13:	td2/2
;l23:	24

;d9:	NOE mixing time
;ns:	4*n
;ds:	32