;hcch_nct_tocsy_ydw_v6
;avance-version
;3D MQ-(H)CCH-TOCSY
;F1 (13C) - F2(13C) - F3(1H)
;	spin-lock time = 94.304*p9*l1 usec

;	Written by Daiwen Yang, Jan. 2004
;     Ref: Y. Zheng et al.  J. Biomol. NMR., 30, 423-429 (2004).
; modified in Jan. 2006, by reducing the phase-cycle from 8 to 4, 
; and also using the INEPT period (d29) for 13C acquisition.
; modified in Apr. 2009: changing several 1H 180 degree pulses into composite 180 pulses
;                        adding p27:gp7
;                        changing p8 @PL11 to p1 @PL1
;                        chnaging ph9=3 to ph9=1

; In order to optimize water suppression, one needs to ajust p17 using GS mode,
; Slightly change gpz4 may improve water suppression

; Note that PL11 is normally 6 dB larger than PL1;
; Note that p17 is often < 2ms; for cryoprobe, p17 is often < 1ms




;$OWNER=fan
#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>

"d13=5u"			

"d0=in0/2-d13/2"
"d20=3u"
"d11=30m"
"d12=20u"
"p2=p1*2"
"p4=p3*2"

"d4=1.4m"			;tau a
"d5=1.0m-p7-p19-d16-p6"
"d6=1.0m-p19-d16"
"d28=3u"
"d29=1.1m-p29-d16"


"DELTA1=1.4m-p16-d16-4u-4*p1/3.1416"
"DELTA2=1.4m-p16-d16-4u-p3"
"DELTA3=1.1m-p29-d16-p6-p1-2*d28-d20"
"DELTA6=d4-p18-d16-4u-4u-4u-p3-3u-p3"
"DELTA7=d4-p18-d16-4u"

"CEN_HC1=(p3-p1)/2"
"CEN_HC2=(p4-p2)/2"
"CEN_HN2=(p22-p2)/2"
"CEN_HN3=(p22-p6)/2"

"l3=(td1/2)"
"l13=(td2/2)"
"in29=(d29-3u)/(l13-1)"
"in20=in29"
"in28=in10-in29"

aqseq 321

1 d11 ze
  d11 
2 d11 do:f2
  d11
3 d11
4 d11 
5 d11 
6 d1 
  50u UNBLKGRAD
  d12 pl1:f1 pl2:f2
  (p3 ph1):f2
  p16:gp6
  d16

  (p1 ph1)
  4u
  p16:gp1
  d16
  DELTA1 pl2:f2
  (center (p2 ph2):f1 (p4 ph1):f2)
  4u
  p16:gp1
  d16
  DELTA2 pl3:f3

  (p3 ph3):f2
   d28 pl0:f2
  (center (p1 ph1 3u p2 ph10 3u p1 ph1):f1 (p6:sp1 ph1):f2 (p22 ph1):f3)
   d28
  (p1 ph2):f1

  d20 
    DELTA3		;1.1m-p29-d16-p22 (or p6)-p1-2*d28-d20
  p29:gp2
  d16 pl2:f2 
 
  (center (p2 ph2):f1 (p4 ph1):f2)
  p29:gp2
  d16 
  d29			;1.1m-p29-d16
  (p3 ph2):f2

  (p1 ph2):f1
  p20:gp5
  d16 pl15:f2 pl11:f1

7 (p9*0.511 ph14):f2
  (p9*1.067 ph16):f2
  (p9*1.822 ph17):f2
  (p9*1.767 ph28):f2
  (p9*1.444 ph15):f2
  (p9*1.767 ph28):f2
  (p9*1.822 ph17):f2
  (p9*1.067 ph16):f2
  (p9*0.511 ph14):f2

  (p9*0.511 ph22):f2
  (p9*1.067 ph24):f2
  (p9*1.822 ph25):f2
  (p9*1.767 ph20):f2
  (p9*1.444 ph23):f2
  (p9*1.767 ph20):f2
  (p9*1.822 ph25):f2
  (p9*1.067 ph24):f2
  (p9*0.511 ph22):f2

  (p9*0.511 ph22):f2
  (p9*1.067 ph24):f2
  (p9*1.822 ph25):f2
  (p9*1.767 ph20):f2
  (p9*1.444 ph23):f2
  (p9*1.767 ph20):f2
  (p9*1.822 ph25):f2
  (p9*1.067 ph24):f2
  (p9*0.511 ph22):f2

  (p9*0.511 ph14):f2
  (p9*1.067 ph16):f2
  (p9*1.822 ph17):f2
  (p9*1.767 ph28):f2
  (p9*1.444 ph15):f2
  (p9*1.767 ph28):f2
  (p9*1.822 ph17):f2
  (p9*1.067 ph16):f2
  (p9*0.511 ph14):f2


  (p9*0.511 ph14):f2
  (p9*1.067 ph16):f2
  (p9*1.822 ph17):f2
  (p9*1.767 ph28):f2
  (p9*1.444 ph15):f2
  (p9*1.767 ph28):f2
  (p9*1.822 ph17):f2
  (p9*1.067 ph16):f2
  (p9*0.511 ph14):f2

  (p9*0.511 ph14):f2
  (p9*1.067 ph16):f2
  (p9*1.822 ph17):f2
  (p9*1.767 ph28):f2
  (p9*1.444 ph15):f2
  (p9*1.767 ph28):f2
  (p9*1.822 ph17):f2
  (p9*1.067 ph16):f2
  (p9*0.511 ph14):f2

  (p9*0.511 ph22):f2
  (p9*1.067 ph24):f2
  (p9*1.822 ph25):f2
  (p9*1.767 ph20):f2
  (p9*1.444 ph23):f2
  (p9*1.767 ph20):f2
  (p9*1.822 ph25):f2
  (p9*1.067 ph24):f2
  (p9*0.511 ph22):f2

  (p9*0.511 ph22):f2
  (p9*1.067 ph24):f2
  (p9*1.822 ph25):f2
  (p9*1.767 ph20):f2
  (p9*1.444 ph23):f2
  (p9*1.767 ph20):f2
  (p9*1.822 ph25):f2
  (p9*1.067 ph24):f2
  (p9*0.511 ph22):f2

  lo to 7 times l1

  (p17 ph1):f1
  3u
  (p17*2 ph2):f1
  4u
  p25:gp4
  d16 pl1:f1
  (p1 ph1):f1
  4u
  p26:gp4
  d16 pl2:f2 pl19:f1

  (p7 ph7):f1
  d13 cpds1:f1 ph1

  (p3 ph4):f2
  d0 pl0:f2
  (center (p6:sp1 ph1):f2 (p22 ph1):f3)
  d0 
  d13 do:f1
  (p7 ph9):f1
  p19:gp3
  d5 pl1:f1 pl2:f2
  d16 

  (center (p2 ph1):f1 (p4 ph6):f2)
  p19:gp3
  d16 
  d6 
 ;(center (p1 ph1):f1  (p3 ph1):f2)
  (p3 ph1):f2

  p27:gp7
  d16
  (p1 ph1):f1
  4u
  p18:gp1
  d16
  DELTA7 
  (center (p1 ph2 3u p2 ph1 3u p1 ph2):f1 (p4 ph1):f2)
  4u
  p18:gp1
  d16
  DELTA6
 (p1 ph1):f1
 (p3 ph1 3u p3 ph5):f2
  4u pl12:f2 
  4u BLKGRAD
  go=2 ph31 cpd2:f2
  d11 do:f2 wr #0 if #0 zd

  d11 ip4 
  lo to 3 times 2
  15m  id0 ip31*2
  15m   
  lo to 4 times l3 
  15m rd0 ip3
  15m  
  lo to 5 times 2
  10m id20 ip31*2
  10m id28 
  10m dd29 
  lo to 6 times l13

exit


ph1=0
ph2=1
ph3=0 0  2 2
ph4=1 3
ph5=0 0  2 2
ph6=0
ph7=1
ph8=0  
ph9=1
ph10=3 3 1 1
ph11=0 
ph12=2
ph14=(16) 0
ph15=(16) 1
ph16=(16) 2
ph17=(16) 3
ph18=(16) 4
ph19=(16) 5
ph20=(16) 6
ph21=(16) 7
ph22=(16) 8
ph23=(16) 9
ph24=(16) 10
ph25=(16) 11
ph26=(16) 12
ph27=(16) 13
ph28=(16) 14
ph29=(16) 15
ph31=0 2 2 0


;pl0 : 120dB
;Channel f1
;pl1: power level for hard high power pulse 
;p1:  90 degree pulse @pl1
;p2: 180 degree pulse @pl1
;pl11: power level for water suppression
;p17: trim pulse[~0.5-1.2ms for H2O sample,adjustable
;pl19: power level for 1H decoupling
;p7; 90 degree flank pulse @pl19 (~40us) 
;cpdprg1: DIPSI2
;pcpd1: 90 degree decoupling pulse (40us)
; O1P --> 4.7ppm on water resonance

;Channel f2
;pl2: power level for hard high power pulse
;p3: 90 degree pulse @pl2
;p4:180 degree pulse @pl2
;pl12: power level for CPD/BB decoupling
;pl15: power level for TOCSY-spinlock
;p9 :  90 degree TOCSY pulse @pl15
;			(~36us @500 MHz; ~33us @600 MHz; ~30us @800 MHz)
;sp1:  power level for shaped 90 degree pulse
;p6 :  180 degree pulse width @sp1, shape: seduce, 200us @800MHz, 270us@600MHz, 300us@500MHz
;spname1: seduce shape 
;spoffsp1:        (176-41)*SpecFreq: 27162Hz @800MHz, 20371@600MHz
;cpdpeg2: GARP
;pcpd2: 90 degree pulse, 70us@800MHz, 90us@600MHz, 100us@500MHz


;O2p: 39ppm (set in spectral parameters), which corresponds to ~41.7 ppm when relative to TSP  


;Channel f3 
;pl3: power level for hard high power pulse (120dB without 15N labeling) 
;p22: 180 degree pulse @pl3

;Gradients 
;gpnam1: SINE.50
;gpnam2: SINE.50
;gpnam3: RECT.1
;gpnam4: SINE.50
;gpnam5: SINE.50
;gpnam6: SINE.100
;gpnam7: SINE.100
;p16: gradient pulse @gpz1 and gpz6, [500 usec]
;gpz1: 40%
;gpz6: 20%
;p18: gradient pulse @gpz1,[300 usec]
;p19: gradient pulse @gpz3,[400 usec]
;gpz3: 30%
;p20: gradient pulse @gpz5,[1000 usec]
;gpz5: -65%
;p25: gradient pulse @gpz4, [2500 usec]
;p26: gradient pulse 4 @gpz4,[2200 usec]
;gpz4: 60%
;p29: gradient pulse 2 @gpz2,[300 usec]
;gpz2: 50%
;p27: gradient pulse @gpz7, [1000us]
;gpz7: 6%

;Other parameters
;d0 : incremented delay (F1 in 3D)              [in0/2-d13/2, -90-180 phase correction]
;d4 : ~1/(4J(CH))                               [1.4 msec]
;d11: delay for disk I/O                        [30 msec]
;d12: delay for power switching                 [20 usec]
;d13:																					  [5 usec]
;d16: delay for gradient recovery               [100 usec]
;l1: loop for FLOPSY cycle:                     [5]
;       mixing time = (p9*94.224*p9) * l1)      [~15 msec]
;l3: loop for phase sensitive 3D using  States-TPPI : l3 = td1/2
;l13: loop for phase sensitive 3D using  States-TPPI : l13 = td2/2
;in0: 1/(2 * SW(C1)), SW(C1) ~ 22 ppm (in the TD1 dimension)
;nd0: 2
;in10: 1/(2 * SW(C2)), SW(C2) ~ 66 ppm (in the TD2 dimension)
;nd10: 2
;NS: 4 * n
;DS: 32
;td1: number of experiments in F1
;td2: number of experiments in F2
;MC2: States-TPPI in F1
;MC2: States-TPPI in F2