;NC_NOESY_3D_ydw
;avance-version
;3D simultaneously 13C,15N-edited NOESY
;13C-edited and 15N-edited NOESY are obtained in two steps:
;   1). separate interleaved two datasets A and B
;   2). A+B gives rise to 13C-edited spectrum; A-B for 15N-edited spectrum
;both aliphatic and aromatic 13C spins are detected.

;Written by Daiwen Yang in Jan. 2005


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"p2=p1*2"
"p22=p21*2"
"d4=1.5m-p14/2"
"d5=2.2m-p16-d16-p11-6u"
"d6=2.2m-p16-d16-p11-6u-4u+p1*2/3.1416"
"d7=1.5m-p16-d16-p14/2"
"d0=3u"
"d11=30m"
"d12=20u"
"d13=5u"
"d10=(in10-p3*4/3.1416-p1*2-p2-6u-20u)/2"
"d20=(in20-p21*4/3.1416-2*p3+p3*4/3.1416-40u)/2"
"d26=2.2m"

"d9=d8-p18-d16"

"DELTA1=d26-1.5m-p14/2"
"DELTA2=d0*2+p13"
"CEN_HN2=(p22-p2)/2"
"DELTA=d1-4*d11-36m"

"l3=(td1/2)"
"l13=(td2/2)"
"l4=1"


aqseq 321


1 ze
  d11 pl12:f2 pl13:f3
2 d11 do:f2 do:f3
  15m
97 9m
3 12m
4 d11*2
5 d11
6 d12 pl0:f2 pl3:f3
  DELTA
  50u UNBLKGRAD
;  (center (p1 ph12 d0 d0 p1 ph1:r):f1 (p14:sp2 ph1):f2 (p22 ph1):f3)
  (p1 ph12):f1
   d0
   (center (p13:sp1 ph1):f2 (p22 ph1):f3)
   d0
   (p2 ph1):f1
   DELTA2
   (p1 ph1:r):f1
  3u
  d9 pl2:f2
  (p21 ph1):f3
  (p3 ph1):f2
  p18:gp5
  d16 pl0:f2
  
  (p1 ph1):f1
  d4 
  (p14:sp2 ph1):f2
  DELTA1
  (CEN_HN2 p2 ph1):f1 (p22 ph1):f3
  d26 
  (p1 ph2):f1 
  3u pl11:f1
  (p11 ph1):f1
  p17:gp1
  d16 pl1:f1

  if "l4%2==1" goto 98
  (p21 ph14):f3
  goto 99

98  (p21 ph8):f3 
99    5u pl22:f2
    5u cpds4:f2
    d20
    5u do:f2
    5u pl2:f2
    (p3 ph3):f2
    d10 gron0
    10u groff
    (p1 ph2 3u p2 ph1 3u p1 ph2):f1
    d10 gron0*-1
    10u groff
    (p3 ph1):f2
    5u pl22:f2
    5u cpds4:f2
    d20
    5u do:f2
    5u pl2:f2
    (p21 ph1):f3

  3u pl11:f1
  (p11 ph1):f1
  3u
  3u pl1:f1

  (p1 ph1):f1
  p16:gp2
  d16
  3u pl11:f1
  (d5 p11 ph11):f1 (d7 p14:sp2 ph1):f2
  3u
  3u pl1:f1
  (CEN_HN2 p2 ph1):f1 (p22 ph1):f3
  3u pl11:f1
  (p11 ph11):f1
  3u
  3u pl1:f1
  p16:gp2
  d16
  d6 pl12:f2 pl13:f3
  4u BLKGRAD
  
  go=2 ph31 cpds2:f2 cpd3:f3
  d11 do:f2 do:f3 wr #0 if #0 zd
  15m iu4
  lo to 97 times 2
  3m ip8 
  3m ip14
  3m ip3
  lo to 3 times 2
  3m id10
  3m id20
  3m ip31
  3m ip31
  lo to 4 times 36
  d11 rd20 ip12 
  d11 rd10 
  lo to 5 times 2
  d11 id0 ip31*2
  lo to 6 times 106
exit
   

ph1=0 
ph2=1
ph3=0 2 
ph8=2 0
ph11=2 
ph12=0 0 2 2 
ph14=0 2
ph31=0 2 2 0

;pl0 : 120dB
;Channel f1
;O1P 	4.7ppm (water)
;pl1: power level for hard high power pulse
;p1:  90 degree high power pulse @PL1
;p2: 180 degree high power pulse, P2=2*p1
;p11: 90 degree soft pulse, ~1.6ms at 800 MHz NMR

;channel f2
;O2P	65ppm
;p3:	90 degree high power pulse @PL2
;p13:	180 degree shaped-pulse @SP1, 300 us at 800 MHz, shape: CaWurst
;p14:	180 degree shaped-pulse @SP2, 600 us at 800 MHz, shape: CaWurst
;p28:	180 degree decoupling shaped-pulse @sp13, 250us at 800 MHz, shape: seduce, offset 111ppm
;pcpd2:	180 degree decoupling shaped-pulse @sp15, 1500us at 800 MHz, shape:smoothedChirp
;CPDPRG2: bi-level or one level adibatic decoupling
;CPDPRG4: 13C MLEV decoupling
;SP14:	~3dB smaller than SP15

;Channel f3
;pl3: power level for hard high power pulse
;p21:	90 degree high power pulse @PL3
;p22: 	180 degree high power pulse, P22=2*P21
;PCPD3:	90 degree hard pulse @PL13, 250 us
;CPDPRG3:	GARP4


;in0: 1/SW(H)/2 = DW(H)
;nd0: 2
;in10: 1/SW(C)/2
;in20: 1/SW(N)/2-1/SW(C)/2

;due to some problems associated with bi-level decoupling, L3 and L13 cannot be used,  
; instead specific values are used.

;d8:	NOE mixing time
;NS: 4 * n
;DS: 32