; CH3_Jcross
; avance-version
; 1H-13C 2D HSQC-based experiment for the measurement of CH/CH cross-correlated 
; relaxation in CH3 groups
; X. Zhang, X. Sui & D.W. Yang, J. Am. Chem. Soc., 128,5073-5081

; O2p=20ppm

; p1 @PL1, 1H 90 hard pulse
; p3 @PL2, 13C 90 hard pulse
;p11 @PL11, 1H 90 soft pulse used in water gate
;p14 @SP2, 13C 180 shaped pulse (reburp, 350 us, center at 40 ppm)
;pcpd2 @PL12, 13C decoupling 90 pulse width (100 us, waltz16 )
; d9 constant time: 28 ms for proteins larger than 14 kDa
;                   28*n ms for smaller proteins
; d8 varies, but should smaller than d9/4
; the maximum acquisition time for 13C can be (d9/4-d8)*4
; Determine ni based on the largest value of d8 that will be used for the experiments


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"d0=3u"
"d11=30m"
"d12=20u"
"p2=p1*2"
"p4=p3*2"
"in6=in0"
"in7=in0"

"d4=1.8m"			
"d13=5u"		
"d5=d9/4+d28-p21-d16-p3*2/3.1416+p1*2+3u-d0"
"d8=d9/4-d28-p21-d16-p3*2/3.1416+p1*2+3u-d0"
"d6=d9/4-d28"
"d7=d9/4+d28"

"DELTA6=d4-3u-p11-3u-p19-d16-2*p3-3u-8u"
"DELTA7=d4-3u-p11-3u-p19-d16"
"DELTA8=1.6m-p18-d16-4u"

"CEN_HC2=(p4-p2)/2"

"l3=(td1/2)"

1 d11 ze
  d11 pl12:f2
2 d11 do:f2
  d11
3 d11
4 d11 
  d1
  50u UNBLKGRAD
  d12 pl2:f2 

  (p3 ph1):f2
  p20:gp7
  d16 pl1:f1

  (p1 ph9):f1
   4u
  p18:gp4
  d16
  DELTA8
  (CEN_HC2 p2 ph1) (p4 ph1):f2
  4u
  p18:gp4
  d16
  DELTA8 pl2:f2
  (p1 ph3):f1

  p17:gp3 
  d16 

  (p3 ph4):f2
  p21:gp6
  d16
  d5
  d0
  (p14:sp2 ph8):f2
  d6 
  (p1 ph3):f1
  3u
  (p2 ph7):f1
  3u
  (p1 ph3):f1
  d7
  (p14:sp2 ph10):f2
  3u
  p21:gp6*-1
  d16
  d8
  d0  
 (p3  ph1):f2
  
  p16:gp5
  d16

  (p1 ph1):f1
  p19:gp1
  d16
  DELTA7
  3u pl11:f1
  (p11 ph12):f1
  3u pl1:f1
  (CEN_HC2 p2 ph1) (p4 ph1):f2
  3u pl11:f1
  (p11 ph12):f1
  4u pl1:f1
  p19:gp1
  d16
  DELTA6 pl2:f2
 (p3 ph1 3u p3 ph5):f2
  4u pl12:f2 
  4u BLKGRAD
  go=2 ph31 cpd2:f2
  d11 do:f2 wr #0 if #0 zd
  d11 ip4
  lo to 3 times 2
  10m  id0
  5m  dd6
  5m  dd7
  10m ip31*2 
  lo to 4 times l3 

exit


ph1=0
ph2=2
ph3=1
ph4=0 
ph6=0 
ph5=0 0 0 0 2 2 2 2
ph7=0 0 2 2
ph8=0 1 2 3 
ph9=0 0 0 0 2 2 2 2
ph10=0 0 1 1 2 2 3 3
ph12=2
ph31=0 2 2 0 2 0 0 2