;CH3T1_ydw
;avance-version

; 1H-13C 2D HSQC-based experiment for the measurement of 13C T1 of CH3 groups

; X. Zhang, X. Sui & D.W. Yang, J. Am. Chem. Soc., 128,5073-5081

; p0 @PL9, 1H 120 hard pulse, @PL9, the 90 pulse width is ~24 us
; p1 @PL1, 1H 90 hard pulse
; p3 @PL2, 13C 90 hard pulse
;p13 @SP2, 13C 180 shaped pulse (reburp, 350 us, center at 40 ppm)
;p22 @PL3, 15N 180 hard pulse
;pcpd1 @PL8, 1H decoupling 90 pulse (pulse width ~40us, dipsi2)
;pcpd2 @PL12, 13C decoupling 90 pulse width (100 us, waltz16 )
;O2P, ~18 ppm

;l1     loop for relaxation delay 5ms*L1
;l4     loop for NOE buildup, 5ms*L4


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


"d0=3u"
"d10=3u"
"d11=30m"
"d12=20u"
"p2=p1*2"
"p4=p3*2"

"d5=13.6m-d0"			
"d6=1.1964m-p18-d16"
"d7=1.6m-p18-d16"
"d8=1.6m-p18-d16-8u-3u-p3-p3"
"d9=2.5m-p0/2"
"d13=5u"		
"d20=13.6m-3u"
"in20=in0"

"CEN_HC1=(p3-p1)/2"
"CEN_HC2=(p4-p2)/2"


"l3=(td1/2)"

1 d11 ze
  d11 pl12:f2
2 d11 do:f2
  d11
3 d11
4 d11 
  d1 
  50u UNBLKGRAD
  d12 pl9:f1 

5  2.5m
   (p0 ph1):f1
   2.5m
   lo to 5 times l4
   d13 pl8:f1 pl2:f2
  
  5u cpds1:f1 ph2 

  (p3 ph3):f2
 
  d20 
  3u pl0:f2 

  (p13:sp2 ph4:r):f2

  d0
  d5 pl2:f2
  (p3 ph1):f2
  5u do:f1
  5u pl9:f1

6  d9 
   (p0 ph1):f1
   d9 
   lo to 6 times l1

   5u pl1:f1
  p16:gp1
  d16

  (p3 ph1):f2
  p18:gp2
  d16
  d6
  (CEN_HC2 p2 ph1) (p4 ph1):f2
  p18:gp2
  d16
  d6
  (CEN_HC1 p1 ph1) (p3 ph2):f2
  p18:gp3
  d16
  d7
  (CEN_HC3 p2 ph1) (p4 ph1):f2
  p18:gp3
  d16
  d8
  (p3 ph1 3u p3 ph5):f2
  4u pl12:f2 
  4u BLKGRAD
  go=2 ph31 cpd2:f2
  d11 do:f2 wr #0 if #0 zd

  d11 ip3 
  lo to 3 times 2
  15m  id0 ip31*2
  15m  dd20 
  lo to 4 times l3 

exit


ph1=0
ph2=1
ph3=0
ph4=0 1 2 3
ph5=0 0 2 2
ph31=0 2